Home

File Information

   

Introduction

In its high level of support for file processing, the .NET Framework provides the FileInfo class. This class is equipped to handle all types of file-related operations including creating, copying, moving, renaming, or deleting a file. FileInfo is based on the FileSystemInfo class that provides information on characteristics of a file.

To assist you with finding information about a file, the FileSystem class from the My object is equipped with a method named GetFileInfo.

Practical LearningPractical Learning: Introducing File Information

  1. Start Microsoft Visual Basic and create a new Windows Application named WattsALoan1
  2. In the Solution Explorer, right-click Form1.vb and click Rename
  3. Type WattsALoan.vb and press Enter
  4. Design the form as follows:
     
    Control Name Text
    Label   Acnt #:
    Label   Customer Name:
    Label   Customer:
    TextBox txtAccountNumber  
    TextBox txtCustomerName  
    Label   Empl #:
    Label   Employee Name:
    Label   Prepared By:
    TextBox txtEmployeeNumber  
    TextBox txtEmployeeName  
    Button btnNewEmployee  
    Label   Loan Amount:
    TextBox txtLoanAmount TextAlign: Right
    Label   Interest Rate:
    TextBox txtInterestRate TextAlign: Right
    Label   %
    Label   Periods
    TextBox   txtPeriods
    TextAlign: Right
    Button btnCalculate Calculate
    Label   Monthly Payment:
    TextBox txtMonthlyPayment  
    Button btnClose Close
  5. Right-click the form and click View Code
  6. Just above the Public Class line, import the System.IO namespace:
     
    Imports System.IO
    
    Public Class WattsALoan
  7. In the Class Name combo box, select btnCalculate
  8. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnCalculate_Click(ByVal sender As System.Object, _
                                       ByVal e As System.EventArgs) _
                                       Handles btnCalculate.Click
            Dim LoanAmount As Double
            Dim InterestRate As Double
            Dim Periods As Double
            Dim MonthlyPayment As Double
    
            Try
                LoanAmount = CDbl(txtLoanAmount.Text)
            Catch ex As Exception
                MsgBox("Invalid Loan Amount")
            End Try
    
            Try
                InterestRate = CDbl(txtInterestRate.Text)
            Catch ex As Exception
    
                MsgBox("Invalid Interest Rate")
            End Try
    
            Try
                Periods = CDbl(txtPeriods.Text)
            Catch ex As Exception
                MsgBox("Invalid Periods Value")
            End Try
    
            MonthlyPayment = Pmt(InterestRate / 12 / 100, _
                                 Periods, -LoanAmount, 0, _
                                 DueDate.BegOfPeriod)
            txtMonthlyPayment.Text = FormatCurrency(MonthlyPayment)
    End Sub
  9. In the Class Name combo box, select btnClose
  10. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnClose_Click(ByVal sender As Object, _
                                   ByVal e As System.EventArgs) _
                                   Handles btnClose.Click
            End
    End Sub
  11. Save the file

File Initialization

The FileInfo class is equipped with one constructor whose syntax is:

Public Sub New(fileName As String)

This constructor takes as argument the name of a file or its complete path. If you provide only the name of the file, the compiler would consider the same directory of its project.

As mentioned previously, to get information about a file, you can call the GetFileInfo() method of the FileSystem class from the My object. Its syntax is:

Public Shared Function GetFileInfo(file As String) As FileInfo

This shared method returns a FileInfo object. Here is an example of calling it:

Imports System.IO

Public Class Exercise

    Private Filename As String

    Private Sub btnFileInformation_Click(ByVal sender As System.Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnFileInformation.Click
        Dim PeopleInformation As FileInfo

        PeopleInformation = My.Computer.FileSystem.GetFileInfo(Filename)
    End Sub
End Class

After calling this method, you can then use its returned value to get the information you want about the file.

Practical LearningPractical Learning: Initializing a File

  1. In the Class Name combo box, select (WattsALoan Events)
  2. In the Method Name combo box, select Load and implement the event as follows:
     
    Private Sub WattsALoan_Load(ByVal sender As Object, _
                                    ByVal e As System.EventArgs) _
                                    Handles Me.Load
            Dim Filename As String = "Employees.wal"
            Dim EmployeeInformation As FileInfo = _
                    My.Computer.FileSystem.GetFileInfo(Filename)
    End Sub
  3. Save the file

File Creation

The FileInfo constructor is mostly meant only to indicate that you want to use a file, whether it exists already or it would be created. Based on this, if you execute an application that has only a FileInfo object created using the constructor as done above, nothing would happen.

To create a file, you have various alternatives. If you want to create one without writing anything in it, which implies creating an empty file, you can call the FileInfo.Create() method. Its syntax is:

Public Function Create As FileStream

This method simply creates an empty file. Here is an example of calling it:

Private Sub btnFileInformation_Click(ByVal sender As System.Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnFileInformation.Click
        Dim PeopleInfo As FileInfo = New FileInfo("People.txt")
        PeopleInfo.Create()
End Sub

The FileInfo.Create() method returns a FileStream object. You can use this returned value to write any type of value into the file, including text. If you want to create a file that contains text, an alternative is to call the FileInfo.CreateText() method. Its syntax is:

Public Function CreateText As StreamWriter

This method returns a StreamWriter object. You can use this returned object to write text to the file.

File Existence

When you call the FileInfo.Create() or the FileInfo.CreateText() method, if the file passed as argument, or as the file in the path of the argument, exists already, it would be deleted and a new one would be created with the same name. This can cause an important file to be deleted. Therefore, before creating a file, you may need to check whether it exists already. To do this, you can check the value of the Boolean FileInfo.Exists property. This property holds a True value if the file exists already and it holds a False value if the file does not yet exist or it does not exist in the path. Here is an example of calling it:

Private Sub btnFileInformation_Click(ByVal sender As System.Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnFileInformation.Click
        Dim Filename As String
        Dim PeopleInformation As FileInfo

        Filename = "Student12.std"
        PeopleInformation = My.Computer.FileSystem.GetFileInfo(Filename)

        If PeopleInformation.Exists = True Then
            MsgBox("The file exists already")
        Else
            MsgBox("Unknown file")
        End If
End Sub

Practical LearningPractical Learning: Creating a Text File

  1. Change the Load event of the form as follows:
     
    Private Sub WattsALoan_Load(ByVal sender As Object, _
                                    ByVal e As System.EventArgs) _
                                    Handles Me.Load
            Dim EmployeeWriter As StreamWriter
            Dim Filename As String = "Employees.wal"
            Dim EmployeeInformation As FileInfo = _
                    My.Computer.FileSystem.GetFileInfo(Filename)
    
            ' If the employees file was not created already,
            ' then create it
            If Not EmployeeInformation.Exists Then
                EmployeeWriter = EmployeeInformation.CreateText()
            End If
    End Sub
  2. Save the file

Writing to a File

As mentioned earlier, the FileInfo.Create() and the FileInfo.CreateText() methods can be used to create a file but they not write values to the file. To write values in the file, each method returns an appropriate object. The  FileInfo.Create() method returns FileStream object. You can use this to specify the type of operation that would be allowed on the file. To write normal text to a file, you can first call the FileInfo.CreateText() method that returns a StreamWriter object. Here is an example:

Private Sub btnSave_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnSave.Click
        Dim Filename As String
        Dim StudentsWriter As StreamWriter
        Dim StudentInformation As FileInfo

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)
        StudentsWriter = StudentInformation.CreateText()

        Try
            StudentsWriter.WriteLine(txtFirstName.Text)
            StudentsWriter.WriteLine(txtLastName.Text)
            StudentsWriter.WriteLine(cbxGenders.SelectedIndex)

            txtFirstName.Text = ""
            txtLastName.Text = ""
            cbxGenders.SelectedIndex = 2
        Finally
            StudentsWriter.Close()
        End Try
End Sub

As an alternative to Create() or CreateText(), if you want to create a file that can only be written to, you can call the FileInfo.OpenWrite() method. Its syntax is:

Public Function OpenWrite As FileStream

This method returns a FileStream that you can then use to write values into the file.

Practical LearningPractical Learning: Writing to a Text File

  1. Change the Load event of the form as follows:
     
    Private Sub WattsALoan_Load(ByVal sender As Object, _
                                    ByVal e As System.EventArgs) _
                                    Handles Me.Load
            Dim EmployeeWriter As StreamWriter
            Dim Filename As String = "Employees.wal"
            Dim EmployeeInformation As FileInfo = _
                    My.Computer.FileSystem.GetFileInfo(Filename)
    
            ' If the employees file was not created already,
            ' then create it
            If Not EmployeeInformation.Exists Then
                EmployeeWriter = EmployeeInformation.CreateText()
    
                ' And create a John Doe employee
                Try
                    EmployeeWriter.WriteLine("00-000")
                    EmployeeWriter.WriteLine("John Doe")
                Finally
                    EmployeeWriter.Close()
                End Try
            End If
    End Sub
  2. Save the file

Appending to a File

You may have created a text-based file and written to it. If you open such a file and find out that a piece of information is missing, you can add that information to the end of the file. To do this, you can call the FileInfo.AppenText() method. Its syntax is:

Public Function AppendText As StreamWriter

When calling this method, you can retrieve the StreamWriter object that it returns, then use that object to add new information to the file.

Practical LearningPractical Learning: Writing to a Text File

  1. To create a new form, on the main menu, click Project -> Add Windows Form...
  2. In the Templates list, make sure Windows Form is selected. Set the Name to NewEmployee and click Add
  3. Design the form as follows:
     
    Control Text Name
    Label Employee #:
    TextBox txtEmployeeNumber
    Label Employee Name:
    TextBox txtEmployeeName
    Button Create btnCreate
    Button Close btnClose
  4. Right-click the form and click View Code
  5. In the top section of the file, just above the Public Class line, import the System.IO namespace:
     
    Imports System.IO
    
    Public Class NewEmployee
    
    End Class
  6. In the Class Name combo box, select btnCreate
  7. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnCreate_Click(ByVal sender As Object, _
                                    ByVal e As System.EventArgs) _
                                    Handles btnCreate.Click
            Dim Filename As String = "Employees.wal"
            Dim EmployeeInformation As FileInfo = New FileInfo(Filename)
            Dim EmployeeWriter As StreamWriter
    
            ' Normally, we should have the file already but just in case...
            If Not EmployeeInformation.Exists Then
                EmployeeWriter = EmployeeInformation.CreateText()
            Else ' If the file exists already, then we will only add to it
                EmployeeWriter = EmployeeInformation.AppendText()
            End If
    
            Try
                EmployeeWriter.WriteLine(txtEmployeeNumber.Text)
                EmployeeWriter.WriteLine(txtEmployeeName.Text)
            Finally
                EmployeeWriter.Close()
            End Try
    
            txtEmployeeNumber.Text = ""
            txtEmployeeName.Text = ""
            txtEmployeeNumber.Focus()
    End Sub
  8. In the Class Name combo box, select btnClose
  9. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnClose_Click(ByVal sender As Object, _
                                   ByVal e As System.EventArgs) _
                                   Handles btnClose.Click
            Close()
    End Sub
  10. In the Solution Explorer, right-click WattsALoan.vb and click View Code
  11. In the Class Name combo box, select btnNewEmployee
  12. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnNewEmployee_Click(ByVal sender As Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnNewEmployee.Click
            Dim FormEmployee As NewEmployee = New NewEmployee()
    
            FormEmployee.ShowDialog()
    End Sub
  13. In the Class Name combo box, select txtEmployeeNumber
  14. In the Method Name combo box, select Leave
  15. Implement the event as follows:
     
    Private Sub txtEmployeeNumber_Leave(ByVal sender As Object, _
                                            ByVal e As System.EventArgs) _
                                            Handles txtEmployeeNumber.Leave
            Dim Found As Boolean
            Dim Filename As String
            Dim EmployeeReader As StreamReader
            Dim EmployeeInformation As FileInfo
            Dim EmployeeNumber As String, EmployeeName As String
    
            Filename = "Employees.wal"
            EmployeeInformation = My.Computer.FileSystem.GetFileInfo(Filename)
    
            If EmployeeInformation.Exists Then
    
                If txtEmployeeNumber.Text = "" Then
                    txtEmployeeName.Text = ""
                    Exit Sub
                Else
                    EmployeeReader = EmployeeInformation.OpenText()
    
                    Try
    
                        Do
                            EmployeeNumber = EmployeeReader.ReadLine()
    
                            If EmployeeNumber = txtEmployeeNumber.Text Then
    
                                EmployeeName = EmployeeReader.ReadLine()
                                txtEmployeeName.Text = EmployeeName
                                Found = True
                            End If
                        Loop While EmployeeReader.Peek() >= 0
    
                        ' When the application has finished checking the file
                    ' if there was no employee with that number, let the user know
                        If Found = False Then
    
                            MsgBox("No employee with that number was found")
                            txtEmployeeName.Text = ""
                            txtEmployeeNumber.Focus()
                        End If
                    Finally
                        EmployeeReader.Close()
                    End Try
                End If
            End If
    End Sub
  16. Execute the application to test it
  17. First create a few employees as follows:
     
    Employee # Employee Name
    42-806 Patricia Katts
    75-148 Helene Mukoko
    36-222 Frank Leandro
    42-808 Gertrude Monay
  18. Process a loan
     
    Watts A Loan
  19. Close the application

Reading from a File

As opposed to writing to a file, you can read from it. To support this, the FileInfo class is equipped with a method named OpenText(). Its syntax is:

Public Function OpenText As StreamReader

This method returns a StreamReader object. You can then use this object to read the lines of a text file. Here is an example:

Private Sub btnOpen_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnOpen.Click
        Dim Filename As String
        Dim StudentsReader As StreamReader
        Dim StudentInformation As FileInfo

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)
        StudentsReader = StudentInformation.OpenText

        Try
            txtFirstName.Text = StudentsReader.ReadLine
            txtLastName.Text = StudentsReader.ReadLine
            cbxGenders.SelectedIndex = CInt(StudentsReader.ReadLine)

        Finally
            StudentsReader.Close()
        End Try
End Sub

If you want to open a file that can only be read from, you can call the FileInfo.OpenRead() method. Its syntax is:

Public Function OpenRead As FileStream

This method returns a FileStream that you can then use to read values from the file.

Routine Operations on Files

 

Opening a File

As opposed to creating a file, probably the second most regular operation performed on a file consists of opening it to read or explore its contents. To support opening a file, the FileInfo class is equipped with the Open() method that is overloaded with three versions. Their syntaxes are:

Public Function Open ( _
	mode As FileMode _
) As FileStream
Public Function Open ( _
	mode As FileMode, _
	access As FileAccess _
) As FileStream
Public Function Open ( _
	mode As FileMode, _
	access As FileAccess, _
	share As FileShare _
) As FileStream

You can select one of these methods, depending on how you want to open the file, using the options for file mode, file access, and file sharing. Each version of this method returns a FileStream object that you can then use to process the file. After opening the file, you can then read or use its content.

Deleting a File

If you have an existing file you don't need anymore, you can delete it. This operation can be performed by calling the FileInfo.Delete() method. Its syntax is:

Public Overrides Sub Delete

Here is an example:

Private Sub btnDelete_Click(ByVal sender As System.Object, _
                                ByVal e As System.EventArgs) _
                                Handles btnDelete.Click
        Dim Filename As String
        Dim StudentInformation As FileInfo

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)

        If PeopleInformation.Exists = True Then
            StudentInformation.Delete()
        Else
            MsgBox("Unknown file")
        End If
End Sub

Copying a File

You can make a copy of a file from one directory to another. To do this, you can call the FileInfo.CopyTo() method that is overloaded with two versions. One of the versions has the following syntax:

public FileInfo CopyTo(string destFileName)

When calling this method, specify the path or directory that will be the destination of the copied file. Here is an example:

Private Sub btnCopy_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnCopy.Click
        Dim Filename As String
        Dim StudentInformation As FileInfo
        Dim MyDocuments As String = _
        	Environment.GetFolderPath(Environment.SpecialFolder.Personal)

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)

        If StudentInformation.Exists = True Then
            StudentInformation.CopyTo(MyDocuments & "\Federal.txt")
        Else
            MsgBox("Unknown file")
        End If
End Sub

In this example, a file named Reality.txt in the directory of the project would be retrieved and its content would be applied to a new file named Federal.txt created in the My Documents folder of the current user.

When calling the first version of the FileInfo.CopyTo() method, if the file exists already, the operation would not continue and you would simply receive a message box. If you insist, you can overwrite the target file. To do this, you can use the second version of this method. Its syntax is:

Public Function CopyTo(destFileName As String, overwrite As Boolean) As FileInfo

The first argument is the same as that of the first version of the method. The second argument specifies what action to take if the file exists already in the target directory. If you want to overwrite it, pass the second argument as true; otherwise, pass it as false. Here is an example:

Private Sub btnCopy_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnCopy.Click
        Dim Filename As String
        Dim StudentInformation As FileInfo
        Dim MyDocuments As String = _
        Environment.GetFolderPath(Environment.SpecialFolder.Personal)

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)

        If StudentInformation.Exists = True Then
            StudentInformation.CopyTo(MyDocuments & "\Federal.txt", True)
        Else
            MsgBox("Unknown file")
        End If
End Sub

Moving a File

If you copy a file from one directory to another, you would have two copies of the same file or the same contents in two files. Instead of copying, if you want, you can simply move a file from one directory to another. This operation can be performed by calling the FileInfo.MoveTo() method. Its syntax is:

Public Sub MoveTo(destFileName As String)

The argument to this method is the same as that of the CopyTo() method. After executing this method, the FileInfo object would be moved to the destFileName path.

Here is an example:

Private Sub btnMove_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnMove.Click
        Dim Filename As String
        Dim StudentInformation As FileInfo
        Dim MyDocuments As String = _
        Environment.GetFolderPath(Environment.SpecialFolder.Personal)

        Filename = "Student1.std"
        StudentInformation = My.Computer.FileSystem.GetFileInfo(Filename)

        If StudentInformation.Exists = True Then
            StudentInformation.MoveTo(MyDocuments & "\Federal.txt")
        Else
            MsgBox("Unknown file")
        End If
End Sub  

 

 

Home Copyright © 2008-2012 FunctionX