Home

XML Reading and Writing

 

Fundamentals of Writing to an XML File

 

Introduction

In previous lessons, we learned to process XML files using the Document Object Model as implemented by the XmlDocument class. To go further and make XML friendlier, the .NET Framework provides many other classes for different purposes, allowing you to create and manage nodes from custom .NET classes.

 

The XML Text Writer Fundamentals

Besides the XmlDocument and the derived classes of XmlNode, the .NET Framework provides the XmlTextWriter class, which is derived from XmlWriter. The XmlTextWriter class works in a top-down approach to create, or deal with, the contents of an XML file. This class writes an XML node and moves down without referring back:

Node Written

This means that, once you have created a node using the XmlTextWriter, you have no way of referring back to it.

To use an XmlTextWriter object, first declare a variable of the type of this class and initialize it using one of its three constructors.

If you had already created a Stream-based object such as declaring a variable of type FileStream but you did not define an encoding scheme, you can pass the Stream-based object to an XmlTextWriter but you must take this time to specify the encoding scheme. To support this concept, the XmlTextWriter provides a constructor with the following syntax:

Public Sub New(w As Stream, encoding As Encoding)

The first argument of this constructor can be a Stream-based variable. The second argument specifies the encoding scheme that would be applied. The default is UTF-8. Based on this, if you want to use the UTF-8 encoding scheme, you can pass it or pass the argument as 0. If you want to use another encoding scheme, pass it to the constructor.

To work from scratch, that is, to initiate a file with manually-created nodes, you can pass the desired name of the file to the XmlTextWriter constructor using the following syntax:

Public Sub New(filename As String, encoding As Encoding)

In this case, you must provide the name of, or path to, the file, whose content you are creating, as the first argument. You must pass the desired encoding scheme as the second argument. Here is an example:

Imports System.Xml
Imports System.IO
Imports System.Text

Public Class Exercise

    Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)
    End Sub
End Class

Eventually, when you have finished using the XmlTextWriter object, you must free the memory it was using by calling the XmlTextWriter.Flush() method. To release the resources that the object was using, call the XmlTextWriter.Close() method. Here is an example:

Imports System.Xml
Imports System.IO
Imports System.Text

Public Class Exercise

    Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.Flush()
        Writer.Close()
    End Sub
End Class

Creating the XML Declaration

Declaring an XmlTextWriter variable allows you to indicate that you intend to create a new XML file. With the variable ready, you can start writing the file's content. As mentioned in previous lessons, an XML file starts at the top with an XML declaration. To create this declaration, you can call the XmlTextWriter.WriteStartDocument() method. This method is overloaded with two versions. The syntax of one of them is:

Public Overrides Sub WriteStartDocument

This method creates a declaration, sets the XML version to 1.0, and includes the encoding scheme you specified in the constructor. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.Flush()
        Writer.Close()
End Sub

To end an XML file, you must close its declaration. This is done by calling the XmlTextWriter.WriteEndDocument() method. Its syntax is:

Public Overrides Sub WriteEndDocument

This method indicates that the XML file has ended and allows the compiler to stop reading it down. This would be done as follows:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

Creating the Root Element

Between the XML declaration and the end of the file, that is, between the call to XmlTextWriter.WriteStartDocument() and the call to XmlTextWriter.WriteEndDocument() methods, you can create the necessary nodes of the file. As reviewed in previous lessons, the most regular node of an XML file is the element. To create an element, the XmlTextWriter class provides the WriteStartElement() method that is overloaded with various versions. One of the versions of this method, and that is inherited from the XmlWriter class, uses the following syntax:

Public Sub WriteStartElement(localName As String)

This method takes as argument the name of the element that will be created. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.WriteStartElement("students")

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

As you may know from XML, every element must be closed. To close an XML element, call the XmlTextWriter.WriteEndElement() method. Its syntax is:

Public Overrides Sub WriteEndElement

When calling this method, always make sure that you know the element it is closing, which must correspond to an appropriate previous call to a WriteStartElement() method. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.WriteStartElement("students")
        Writer.WriteEndElement()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

This would produce:

XML Preview

As you can see from the result, a single or the first call to the WriteStartElement() method creates the root element that is required for every XML file. This means that, after this (first) call but before its corresponding WriteEndElement() call, you can create the necessary nodes that you want to include as part of the file.

Creating the Child Elements of the Root

To help you create child elements of the root node, you can keep calling the XmlTextWriter.WriteStartElement() method as necessary and appropriately closing it. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
    Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

    Writer.WriteStartDocument()

    Writer.WriteStartElement("students")

        Writer.WriteStartElement("student")
        Writer.WriteEndElement()

        Writer.WriteEndElement()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

If you simply call this method as done above, the element would be empty. Based on this, the above code would produce:

XML Preview

If you want the element to have a value, call the XmlTextWriter.WriteString() method. Its syntax is:

Public Overrides Sub WriteString(text As String)

This method must immediately follow the call to WriteStartElement() that creates a new element. It takes as argument the value for the immediately previously defined element. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.WriteStartElement("students")

        Writer.WriteStartElement("student")
        Writer.WriteString("Raymond Sanson")
        Writer.WriteEndElement()

        Writer.WriteEndElement()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

 This would produce:

XML Preview

If you call the XmlTextWriter.WriteStartElement() method and you want the element to have a value, remember to call the XmlTextWriter.WriteString() method, and then call the XmlTextWriter.WriteEndElement() method. An alternative is to call the XmlWriter.WriteElementString() method that comes in two versions. The syntax of one of these versions is:

Public Sub WriteElementString(localName As String, _
			      value As String)

The first argument to this method is the name of the element that will be created. The second argument is the value of the element. This method creates and closes its element. Here is an example:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = _
            New XmlTextWriter("students.xml", Encoding.UTF8)

        Writer.WriteStartDocument()

        Writer.WriteStartElement("students")

        Writer.WriteStartElement("student")
        Writer.WriteString("Raymond Sanson")
        Writer.WriteEndElement()

        Writer.WriteElementString("student", "Brigitte Arano")

        Writer.WriteEndElement()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

This would produce:

XML Preview

In the same way, you can create the necessary elements and their child elements as necessary. Be careful to appropriately start an element and remember to close it if necessary. Here are examples:

Private Sub btnDocument_Click(ByVal sender As Object, _
                                  ByVal e As System.EventArgs) _
                                  Handles btnDocument.Click
        Dim Writer As XmlTextWriter = New XmlTextWriter("students.xml", _
                                                    Encoding.UTF8)

        Writer.WriteStartDocument()

        ' Create the root element named students
        Writer.WriteStartElement("students")

        ' Start a child element named student
        Writer.WriteStartElement("student")

        ' Create a number for the student
        Writer.WriteStartElement("studentnumber")
        Writer.WriteString("740597")
        Writer.WriteEndElement()

        ' Create a name for the student
        Writer.WriteStartElement("fullname")
        Writer.WriteString("Christie Aronson")
        Writer.WriteEndElement()

        ' Create a date of birth for the student
        Writer.WriteStartElement("dateofbirth")
        Writer.WriteString("02/16/1988")
        Writer.WriteEndElement()

        ' Create a Format child element to the Video element
        Writer.WriteStartElement("Gender")
        Writer.WriteString("Female")
        Writer.WriteEndElement()

        ' Close the student node
        Writer.WriteEndElement()

        ' Start a new student element
        Writer.WriteStartElement("student")

        ' Create the child elements of the new student element
        Writer.WriteElementString("studentnumber", "249575")
        Writer.WriteElementString("fullname", "Julius Raymonds")
        Writer.WriteElementString("dateofbirth", "12/07/1992")
        Writer.WriteElementString("Gender", "Male")
        ' The current student node
        Writer.WriteEndElement()

        ' Close the root element
        Writer.WriteEndElement()

        Writer.WriteEndDocument()

        Writer.Flush()
        Writer.Close()
End Sub

This would produce:

XML Preview

 

Saving a File As XML

If you are creating a text-intensive document and you want to save it as an XML file, for example if you have declared a variable of type TextWriter-derived class (such as StringWriter or StreamWriter), you can use that file to initialize the XmlTextWriter variable. To support TextWriter documents, the XmlTextWriter class is equipped with a constructor with the following syntax:

Public Sub New(w As TextWriter)

This constructor expects as argument a TextWriter-based object. This means that you should have defined the TextWriter object prior to passing it to this constructor. This also implies that the TextWriter was used to specify the encoding scheme that would be used. Here is an example:

Private Sub btnCreate_Click(ByVal sender As Object, _
                                ByVal e As System.EventArgs) _
                                Handles btnCreate.Click
    Dim Filename As String = "students.xml"
    Dim fleStream As FileStream = _
	New FileStream("students.xml", FileMode.Create, _
                       FileAccess.Write, FileShare.None)
    Dim stmWriter As StreamWriter = New StreamWriter(fleStream)
    Dim txtWriter As XmlTextWriter = New XmlTextWriter(stmWriter)

    stmWriter.Flush()
    stmWriter.Close()
End Sub

To actually write the contents of the document, you can create each paragraph by calling the XmlTextWriter.WriteStartElement() method the same way we did earlier. Here is an example:

Private Sub btnCreate_Click(ByVal sender As Object, _
                                ByVal e As System.EventArgs) _
                                Handles btnCreate.Click
        Dim Filename As String = "students.xml"
        Dim fleStream As FileStream = New FileStream("students.xml", _
                      FileMode.Create, _
                      FileAccess.Write, _
                      FileShare.None)
        Dim stmWriter As StreamWriter = New StreamWriter(fleStream)
        Dim txtWriter As XmlTextWriter = New XmlTextWriter(stmWriter)

        txtWriter.WriteStartDocument()
        txtWriter.WriteStartElement("ToAllEmployees")

        For i As Integer = 0 To txtEditor.Lines.Length - 1
            txtWriter.WriteStartElement("Notice")
            txtWriter.WriteString(txtEditor.Lines(i))
            txtWriter.WriteEndElement()
        Next

        txtWriter.WriteEndDocument()

        stmWriter.Flush()
        stmWriter.Close()
End Sub

Reading From an XML File

 

Introduction

Once an XML file exists, you can read it to retrieve the values of its nodes. To support opening an XML file and reading its contents, the .NET Framework provides the XmlTextReader class that is derived from the XmlReader class. The XmlTextReader class is equipped with all the necessary properties and methods to explore the contents of an XML file.

Like XmlTextWriter, the XmlTextReader class reads a file from top to bottom without going back up once it has passed a node:

Node Read

This means that, when using the XmlTextReader class to read an XML file, once you have read a node and moved down the file, you cannot refer back to the previous node and you cannot access a previous node.

Using and XML Text Reader

To use an XML text reader, declare a variable of type XmlTextReader and initialize it with one of its constructors. The class is equipped with 14 constructors. If you want to open a file whose name or path you know, use the following constructor:

Public Sub New(url As String)

This constructor takes as argument the name of, or path to, an XML file. If the file is found, it would be opened. If the file does not exist or there is an error in the string that specifies its path, the compiler would throw an XmlException exception.

Reading Nodes

After declaring an XmlTextReader variable, you can start reading the content of the file. To support this, you can call the XmlTextReader.Read() method. Its syntax is:

Public Overrides Function Read As Boolean

As mentioned previously, the file is read from top to bottom. Based on this, when you call the Read() method, it reads the first node, moves to the next, and so on until it reaches the end of the file. While reading the file, every time this method reaches a node, you can find out what type of node it is by checking the XmlTextReader.NodeType property. This can help you take a specific action if the reached node meets a certain criterion.

As reviewed in our introductions to XML, each node has a name and possibly a value. You can find out the name of a node by checking the XmlTextReader.Name property. To know the value of a node, retrieve its XmlTextReader.Value property. 

Details on XML Reading and Writing

 

Indentation

Consider a valid XML file such as the following, opened in Notepad:

Notepad

If you were asked to examine this file, you can see that its crowded words make it difficult to read. To include a white space when writing to the file, you can call the XmlTextWriter.WriteWhiteSpace() method. Its syntax is:

Public Overrides Sub WriteWhitespace(ws As String)

Besides white spaces, indentation consists of setting empty spaces on the left of child nodes to make the file easier to read. Based on this, indentation is not a requirement but a convenience. While the WriteWhiteSpace() method allows you to explicitly create a white space in the file, the XmlTextWriter class is equipped with the Formatting property. This property is a value of the Formatting enumeration. The Formatting enumeration has two members. The Indented value ensures that each child node would be indented from its parent.

If you manually create an XML file, whether using Notepad, Visual Studio, or another text editor, you can indent the nodes as you see fit. To let the compiler know that you want the nodes to be indented, assign the Formatting.Indented member to its Formatting property. Here is an example:

Private Sub btnCreate_Click(ByVal sender As Object, _
                                ByVal e As System.EventArgs) _
                                Handles btnCreate.Click
    Dim Filename As String = "students.xml"
    Dim fleStream As FileStream = _
	New FileStream("students.xml", FileMode.Create, _
                       FileAccess.Write, FileShare.None)
    Dim stmWriter As StreamWriter = New StreamWriter(fleStream)
    Dim txtWriter As XmlTextWriter = New XmlTextWriter(stmWriter)

    Writer.Formatting = Formatting.Indented

    stmWriter.Flush()
    stmWriter.Close()
End Sub

If you manually create an XML file, you can specify the number of empty spaces on the left of a node by pressing the Space bar a few times before typing the node. Most people use 2 or 4 characters for the indentation. If you are programmatically creating the file, to specify the number of characters that should be used during indentation, assign the desired integer to the XmlTextWriter.Indentation property. If you don't use this property, the compiler would use two characters. You can also find out the number of characters used for indentation by retrieving the value of this property.

As mentioned above, indentation consists of entering white spaces on the left of child nodes. Instead of empty spaces, if you want to use another character, assign it to the XmlTextWriter.IndentChar property.

 

Previous Copyright © 2008-2012 FunctionX Home