Home

Example Application: Altair Realtors

 

Introduction

Altair Realtors is a fictitious real estate companies that sells different types of properties, including single families, townhouses (or town homes), and condominiums. This application is mainly used to present some of the available properties to a potential customer.

An XML attribute is a sub-element that is created as part of a parent element. This application is used to explore the techniques of managing XML attributes.

 

Practical Learning: Creating the Application

  1. Start Microsoft Visual Basic and create a Windows Application named AltairRealtors1
  2. To create a new form, on the main menu, click Projects -> Add Windows Form...
  3. Set the Name to PropertyEditor and click Add
  4. Design the form as follows:
     
    Altair Realtors: Property Editor
    Control Text Name Other Properties
    Label Label Property Code:    
    TextBox TextBox   txtPropertyCode Modifiers: Public
    Label Label Status    
    ComboBox ComboBox   cbxStatus Modifiers: Public
    Items:
    Sold
    Available
    Needs Repair
    Label Label      
    DateTimePicker   dtpDateListed Modifiers: Public
    Format: Short
    Label Label Year Built:    
    TextBox TextBox   txtYearBuilt  
    Label Label Property Type:    
    ComboBox ComboBox   cbxPropertyTypes Modifiers: Public
    Items:
    Unknown
    Single Family
    Townhouse
    Condominium
    Label Label Style:    
    ComboBox ComboBox   cbxStyles Modifiers: Public
    Items:
    Farm
    Colonial
    Victorian
    Contemporary
    Label Label Address:    
    TextBox TextBox   txtAddress Modifiers: Public
    Label Label City:    
    TextBox TextBox   txtCity Modifiers: Public
    Label Label Location:    
    TextBox TextBox   txtLocation Modifiers: Public
    Label Label State:    
    ComboBox ComboBox   cbxStates Modifiers: Public
    Items:
    DC
    MD
    PA
    VA
    WV
    Label Label ZIP Code:    
    TextBox TextBox   txtZIPCode Modifiers: Public
    Label Label Stories    
    TextBox TextBox 0 txtStories Modifiers: Public
    Label Label Bedrooms:    
    TextBox TextBox 0 txtBedrooms Modifiers: Public
    Label Label Bathrooms:    
    TextBox TextBox 0.0 txtBathrooms Modifiers: Public
    Label Label Condition:    
    ComboBox ComboBox   cbxConditions Modifiers: Public
    Items:
    Good
    Excellent
    Needs Repairs
    Label Label Market Value:    
    TextBox TextBox 0.00 txtMarketValue Modifiers: Public
    Label Label Picture Path:    
    TextBox TextBox   txtPicturePath Modifiers: Public
    Enabled: False
    Button Button Select Picture... btnPicture  
    PictureBox   pbxProperty Modifiers: Public
    SizeMode: Zoom
    Button Button OK btnOK DialogResult: OK
    Button Button Cancel btnCancel DialogResult: Cancel
    OpenFileDialog (Name): dlgPicture
    Title: Select Property Picture
    DefaultExt: jpg
    Filter: JPEG Files (*.jpg,*.jpeg)|*.jpg|GIF Files (*.gif)|*.gif|Bitmap Files (*.bmp)|*.bmp|PNG Files (*.png)|*.png
    Form
    FormBorderStyle: FixedDialog
    Text: Altair Realtors - Property Editor
    StartPosition: CenterScreen
    AcceptButton: btnOK
    CancelButton: btnCancel
    MaximizeBox: False
    MinimizeBox: False
    ShowInTaskBar: False
  5. Double-click the Select Picture button and implement its event as follows:
     
    Private Sub btnPicture_Click(ByVal sender As System.Object, _
                                     ByVal e As System.EventArgs) _
                                     Handles btnPicture.Click
            If dlgPicture.ShowDialog() = DialogResult.OK Then
                txtPicturePath.Text = dlgPicture.FileName
                pbxProperty.Image = Image.FromFile(txtPicturePath.Text)
            End If
    End Sub
  6. In the Solution Explorer, right-click Form1.vb and click Rename
  7. Type RealEstate.vb and press Enter twice (to display that form)
  8. From the Toolbox, add a ListView to the form
  9. While the new list view is still selected, in the Properties window, click the ellipsis button of the Columns field and create the columns as follows:
     
    (Name) Text TextAlign Width
    colIndex #   40
    colPropertyCode Prop Code Center 65
    colPropertyType Property Type   80
    colPropertyCondition Condition   65
    colLocation Location   70
    colStories Stories Right 45
    colBedrooms Bedrooms Right 62
    colBathrooms Bathrooms Right 62
    colMarketValue Market Value Right 75
  10. Design the form as follows: 
     
    Altair Realtors
     
    Control Text Name Other Properties
    ListView   lvwAllocations View: Details
    GridLines: True
    FullRowSelect: True
    Anchor: Top, Bottom, Left, Right
    PictureBox   pbxProperty Anchor: Bottom, Left
    Label Description   Anchor: Bottom, Right
    TextBox   txtDescription Multiline: True
    Anchor: Bottom, Right
    Button New Property... btnNewProperty Anchor: Bottom, Right
    Button Close btnClose Anchor: Bottom, Right
  11. Right-click the form and click View Code
  12. Above the Public Class line, add the following lines
     
    Imports System.IO
    Imports System.Xml
    
    Public Class RealEstate
    
    End Class
  13. In the Class Name combo box, select btnNewProperty
  14. In the Method Name combo box, select Click and implement the event as follows:
     
    Imports System.IO
    Imports System.Xml
    
    Public Class RealEstate
    
        Private Sub btnNewProperty_Click(ByVal sender As Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnNewProperty.Click
            ' Get a reference to the property editor
            Dim Editor As PropertyEditor = New PropertyEditor
            Dim Filename As String = "properties.xml"
    
            If Editor.ShowDialog() = DialogResult.OK Then
                Dim PropertyType As String, Location As String
                Dim Stories As Integer, Bedrooms As Integer
                Dim Bathrooms As Single
                Dim MarketValue As Double
    
                ' We will need a reference to the XML document
                Dim DOMProperties As XmlDocument = New XmlDocument
    
                ' Find out if the file exists already
                ' If it doesn't, then create it
                If Not File.Exists(Filename) Then
                    DOMProperties.LoadXml( _
    			"<?xml version=""1.0"" encoding=""utf-8""?>" & _
                                          "<Listing></Listing>")
                    DOMProperties.Save(Filename)
                End If
    
                ' Open the XML file
                DOMProperties.Load(Filename)
    
                ' Get a reference to the root node
                Dim RootElement As XmlElement = DOMProperties.DocumentElement
    
                PropertyType = Editor.cbxPropertyTypes.Text
                Location = Editor.txtLocation.Text
                Stories = CInt(Editor.txtStories.Text)
                Bedrooms = CInt(Editor.txtBedrooms.Text)
                Bathrooms = CSng(Editor.txtBathrooms.Text)
                MarketValue = CDbl(Editor.txtMarketValue.Text)
    
                ' Create a node named Property
                Dim PropertyElement As XmlElement = _
    		DOMProperties.CreateElement("Property")
                ' Add it to the root element
                RootElement.AppendChild(PropertyElement)
    
                ' Create a node named PropertyType
                PropertyElement = DOMProperties.CreateElement("PropertyType")
                Dim TextProperty As XmlText = _
    		DOMProperties.CreateTextNode(PropertyType)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Location
                PropertyElement = DOMProperties.CreateElement("Location")
                TextProperty = DOMProperties.CreateTextNode(Location)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Stories
                PropertyElement = DOMProperties.CreateElement("Stories")
                TextProperty = DOMProperties.CreateTextNode(Stories.ToString())
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bedrooms
                PropertyElement = DOMProperties.CreateElement("Bedrooms")
                TextProperty = DOMProperties.CreateTextNode(Bedrooms.ToString())
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bathrooms
                PropertyElement = DOMProperties.CreateElement("Bathrooms")
                TextProperty = _
    		DOMProperties.CreateTextNode(Bathrooms.ToString("F"))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named MarketValue
                PropertyElement = DOMProperties.CreateElement("MarketValue")
                TextProperty = _
    		DOMProperties.CreateTextNode(MarketValue.ToString("F"))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Save the XML file
                DOMProperties.Save(Filename)
            End If
        End Sub
    End Class
  15. Execute the application
  16. Click the New Property button
  17. Enter the following pieces of information:
     
    Property Type Single Family
    Location White Oak
    Stories 2
    Bedrooms 3
    Bathrooms 2.5
    Market Value 465580
  18. Click OK
  19. Close the form and return to your programming environment
  20. From the main menu of Visual Studio, open the properties.xml file from the AltairRealtors1\AltairRealtors\bin\Debug folder: 

    <?xml version="1.0" encoding="utf-8"?>
    <Listing>
      <Property>
        <PropertyType>Single Family</PropertyType>
        <Location>White Oak</Location>
        <Stories>2</Stories>
        <Bedrooms>3</Bedrooms>
        <Bathrooms>2.50</Bathrooms>
        <MarketValue>365580.00</MarketValue>
      </Property>
    </Listing>
  21. Display the RealEstate.vb file
  22. To set attributes of a node, change the file as follows:
     
    Imports System.IO
    Imports System.Xml
    
    Public Class RealEstate
    
        Private Sub btnNewProperty_Click(ByVal sender As Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnNewProperty.Click
            ' Get a reference to the property editor
            Dim Editor As PropertyEditor = New PropertyEditor
    
            Dim Filename As String = "properties.xml"
    
            Dim RndNumber As Random = New Random
            Editor.txtPropertyCode.Text = RndNumber.Next(100, 999).ToString() & _
                                          "-" & RndNumber.Next(100, 999)
    
            If Editor.ShowDialog() = DialogResult.OK Then
                Dim PropertyCode As String
                Dim PropertyType As String
                Dim Location As String
                Dim SaleStatus As String
                Dim Stories As Integer, Bedrooms As Integer
                Dim Bathrooms As Single
                Dim MarketValue As Double
    
                ' We will need a reference to the XML document
                Dim DOMProperties As XmlDocument = New XmlDocument
    
                ' Find out if the file exists already
                ' If it doesn't, then create it
                If Not File.Exists(Filename) Then
                    DOMProperties.LoadXml( _
    			"<?xml version=""1.0"" encoding=""utf-8""?>" & _
                                      "<Listing></Listing>")
                    DOMProperties.Save(Filename)
                End If
    
                ' Open the XML file
                DOMProperties.Load(Filename)
    
                PropertyCode = Editor.txtPropertyCode.Text
                SaleStatus = Editor.cbxStatus.Text
                PropertyType = Editor.cbxPropertyTypes.Text
                Location = Editor.txtLocation.Text
                Stories = CInt(Editor.txtStories.Text)
                Bedrooms = CInt(Editor.txtBedrooms.Text)
                Bathrooms = CSng(Editor.txtBathrooms.Text)
                MarketValue = CDbl(Editor.txtMarketValue.Text)
    
                ' Get a reference to the root element
                Dim RootElement As XmlElement = DOMProperties.DocumentElement
                ' Create a node named Property
                Dim PropertyElement As XmlElement = _
    		DOMProperties.CreateElement("Property")
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Code", PropertyCode)
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Status", SaleStatus)
    
                ' Add it to the root element
                RootElement.AppendChild(PropertyElement)
    
                . . . No Change
    
                ' Save the XML file
                DOMProperties.Save(Filename)
            End If
        End Sub
    End Class
  23. Execute the application
  24. Click the New Property button
  25. Enter the following pieces of information:
     
    Status Sold
    Property Type Single Family
    Location Arlington Cemetery
    Stories 3
    Bedrooms 5
    Bathrooms 3.5
    Market Value 675880
  26. Click OK
  27. Close the form and return to your programming environment
  28. In Visual Studio, access the properties.xml tab to see the file (the value of the Code attribute will be different from yours):
     
    <?xml version="1.0" encoding="utf-8"?>
    <Listing>
      <Property>
        <PropertyType>Single Family</PropertyType>
        <Location>White Oak</Location>
        <Stories>2</Stories>
        <Bedrooms>3</Bedrooms>
        <Bathrooms>2.50</Bathrooms>
        <MarketValue>365580.00</MarketValue>
      </Property>
      <Property Code="700-326" Status="Sold">
        <PropertyType>Single Family</PropertyType>
        <Location>Arlington Cemetery</Location>
        <Stories>3</Stories>
        <Bedrooms>5</Bedrooms>
        <Bathrooms>3.50</Bathrooms>
        <MarketValue>675880.00</MarketValue>
      </Property>
    </Listing>
  29. Display the RealEstate.vb file
  30. To add a few attributes, change the file as follows:
     
    Imports System.IO
    Imports System.Xml
    
    Public Class RealEstate
    
        Private Sub btnNewProperty_Click(ByVal sender As Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnNewProperty.Click
            ' Get a reference to the property editor
            Dim Editor As PropertyEditor = New PropertyEditor
            ' If this directory doesn't exist, create it
            Directory.CreateDirectory("C:\Altair Realtors")
            ' This is the XML file that holds the list of proeprties
            Dim Filename As String = "C:\Altair Realtors\properties.xml"
    
            Dim RndNumber As Random = New Random
            Editor.txtPropertyCode.Text = RndNumber.Next(100, 999) & _
                                      "-" & RndNumber.Next(100, 999).ToString()
    
            If Editor.ShowDialog() = DialogResult.OK Then
                Dim PropertyCode As String, PropertyType As String
                Dim Location As String, SaleStatus As String
                Dim Style As String, Condition As String
                Dim YearBuilt As Integer, Stories As Integer
    	    Dim Bedrooms As Integer
                Dim Bathrooms As Single
                Dim MarketValue As Double
    
                ' We will need a reference to the XML document
                Dim DOMProperties As XmlDocument = New XmlDocument
    
                ' Find out if the file exists already
                ' If it doesn't, then create it
                If Not File.Exists(Filename) Then
                    DOMProperties.LoadXml( _
    			"<?xml version=""1.0"" encoding=""utf-8""?>" & _
                                          "<Listing></Listing>")
                    DOMProperties.Save(Filename)
                End If
    
                ' Open the XML file
                DOMProperties.Load(Filename)
    
                PropertyCode = Editor.txtPropertyCode.Text
                Location = Editor.txtLocation.Text
                SaleStatus = Editor.cbxStatus.Text
                YearBuilt = CInt(Editor.txtYearBuilt.Text)
                PropertyType = Editor.cbxPropertyTypes.Text
                Style = Editor.cbxStyle.Text
                Condition = Editor.cbxConditions.Text
                Bedrooms = CInt(Editor.txtBedrooms.Text)
                Bathrooms = CSng(Editor.txtBathrooms.Text)
                MarketValue = CDbl(Editor.txtMarketValue.Text)
    
                ' Get a reference to the root element
                Dim RootElement As XmlElement = DOMProperties.DocumentElement
                ' Create a node named Property
                Dim PropertyElement As XmlElement = _
    		DOMProperties.CreateElement("Property")
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Code", PropertyCode)
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Status", SaleStatus)
                ' Add it to the root element
                RootElement.AppendChild(PropertyElement)
    
                ' Create a node named Property
                PropertyElement = DOMProperties.CreateElement("DateListed")
                RootElement.LastChild.AppendChild(PropertyElement)
    
                ' Create an attribute for the DateListed element
                Dim atrProperty As XmlAttribute = _
    		DOMProperties.CreateAttribute("YearBuilt")
                atrProperty.Value = YearBuilt
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create a node named PropertyType
                PropertyElement = DOMProperties.CreateElement("PropertyType")
                Dim TextProperty As XmlText = _
    		DOMProperties.CreateTextNode(PropertyType)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create an attribute for the PropertyType element
                atrProperty = DOMProperties.CreateAttribute("Style")
                atrProperty.Value = Style
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create an attribute for the Condition element
                atrProperty = DOMProperties.CreateAttribute("Condition")
                atrProperty.Value = Condition
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create a node named Location
                PropertyElement = DOMProperties.CreateElement("Location")
                TextProperty = DOMProperties.CreateTextNode(Location)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Stories
                PropertyElement = DOMProperties.CreateElement("Stories")
                TextProperty = DOMProperties.CreateTextNode(Stories)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bedrooms
                PropertyElement = DOMProperties.CreateElement("Bedrooms")
                TextProperty = DOMProperties.CreateTextNode(Bedrooms)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bathrooms
                PropertyElement = DOMProperties.CreateElement("Bathrooms")
                TextProperty = _
    		DOMProperties.CreateTextNode(FormatNumber(Bathrooms))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named MarketValue
                PropertyElement = DOMProperties.CreateElement("MarketValue")
                TextProperty = _
    		DOMProperties.CreateTextNode(FormatNumber(MarketValue))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Save the XML file
                DOMProperties.Save(Filename)
            End If
        End Sub
    End Class
  31. Save the file
  32. To add a few attributes, change the file as follows:
     
    Imports System.IO
    Imports System.Xml
    
    Public Class RealEstate
    
        Private Sub btnNewProperty_Click(ByVal sender As Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnNewProperty.Click
            ' Get a reference to the property editor
            Dim Editor As PropertyEditor = New PropertyEditor
            ' If this directory doesn't exist, create it
            Dim strDirectory As String = "C:\Altair Realtors"
            Directory.CreateDirectory(strDirectory)
            ' This is the XML file that holds the list of proeprties
            Dim Filename As String = "C:\Altair Realtors\properties.xml"
    
            Dim RndNumber As Random = New Random
            Editor.txtPropertyCode.Text = RndNumber.Next(100, 999) & _
                                          "-" & RndNumber.Next(100, 999)
            Dim strPicturePath As String
    
            If Editor.ShowDialog() = DialogResult.OK Then
                Dim PropertyCode As String, PropertyType As String
                Dim Location As String, SaleStatus As String
                Dim Style As String, Condition As String
                Dim Address As String, City As String, State As String
                Dim ZIPCode As String, Description As String
                Dim DateListed As Date
                Dim YearBuilt As Integer, Stories As Integer, Bedrooms As Integer
                Dim Bathrooms As Single
                Dim MarketValue As Double
    
                ' We will need a reference to the XML document
                Dim DOMProperties As XmlDocument = New XmlDocument
    
                ' Find out if the file exists already
                ' If it doesn't, then create it
                If Not File.Exists(Filename) Then
                    DOMProperties.LoadXml( _
    			"<?xml version=""1.0"" encoding=""utf-8""?>" & _
                                          "<Listing></Listing>")
                    DOMProperties.Save(Filename)
                End If
    
                ' Open the XML file
                DOMProperties.Load(Filename)
    
                PropertyCode = Editor.txtPropertyCode.Text
                SaleStatus = Editor.cbxStatus.Text
                DateListed = Editor.dtpDateListed.Value
                YearBuilt = CInt(Editor.txtYearBuilt.Text)
                PropertyType = Editor.cbxPropertyTypes.Text
                Style = Editor.cbxStyle.Text
                Condition = Editor.cbxConditions.Text
                Location = Editor.txtLocation.Text
                Address = Editor.txtAddress.Text
                City = Editor.txtCity.Text
                State = Editor.cbxStates.Text
                ZIPCode = Editor.txtZIPCode.Text
                Stories = CInt(Editor.txtStories.Text)
                Bedrooms = CInt(Editor.txtBedrooms.Text)
                Bathrooms = CSng(Editor.txtBathrooms.Text)
                Description = Editor.txtDescription.Text
                MarketValue = CDbl(Editor.txtMarketValue.Text)
                strPicturePath = Editor.txtPicturePath.Text
    
                ' Get a reference to the root element
                Dim RootElement As XmlElement = DOMProperties.DocumentElement
                ' Create a node named Property
                Dim PropertyElement As XmlElement = _
    		DOMProperties.CreateElement("Property")
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Code", PropertyCode)
    
                ' Create an attribute for the Propety node
                PropertyElement.SetAttribute("Status", SaleStatus)
                ' Add it to the root element
                RootElement.AppendChild(PropertyElement)
    
                ' Create a node named Property
                PropertyElement = DOMProperties.CreateElement("DateListed")
                Dim TextProperty As XmlText = _
    		DOMProperties.CreateTextNode(DateListed.ToString("d"))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
                RootElement.LastChild.AppendChild(PropertyElement)
    
                ' Create an attribute for the DateListed element
                Dim atrProperty As XmlAttribute = _
    		DOMProperties.CreateAttribute("YearBuilt")
                atrProperty.Value = YearBuilt
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create a node named PropertyType
                PropertyElement = DOMProperties.CreateElement("PropertyType")
                TextProperty = DOMProperties.CreateTextNode(PropertyType)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create an attribute for the PropertyType element
                atrProperty = DOMProperties.CreateAttribute("Style")
                atrProperty.Value = Style
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create an attribute for the PropertyType element
                atrProperty = DOMProperties.CreateAttribute("Condition")
                atrProperty.Value = Condition
                PropertyElement.SetAttributeNode(atrProperty)
    
                ' Create a node named Location
                PropertyElement = DOMProperties.CreateElement("Location")
                TextProperty = DOMProperties.CreateTextNode(Location)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create some attributes for the Location element
                atrProperty = DOMProperties.CreateAttribute("Address")
                atrProperty.Value = Address
                PropertyElement.Attributes.Append(atrProperty)
    
                atrProperty = DOMProperties.CreateAttribute("City")
                atrProperty.Value = City
                PropertyElement.Attributes.Append(atrProperty)
    
                atrProperty = DOMProperties.CreateAttribute("State")
                atrProperty.Value = State
                PropertyElement.Attributes.Append(atrProperty)
    
                atrProperty = DOMProperties.CreateAttribute("ZIPCode")
                atrProperty.Value = ZIPCode
                PropertyElement.Attributes.Append(atrProperty)
    
                ' Create a node named Stories
                PropertyElement = DOMProperties.CreateElement("Stories")
                TextProperty = DOMProperties.CreateTextNode(Stories.ToString())
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bedrooms
                PropertyElement = DOMProperties.CreateElement("Bedrooms")
                TextProperty = DOMProperties.CreateTextNode(Bedrooms.ToString())
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Bathrooms
                PropertyElement = DOMProperties.CreateElement("Bathrooms")
                TextProperty = _
    		DOMProperties.CreateTextNode(FormatNumber(Bathrooms))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named MarketValue
                PropertyElement = DOMProperties.CreateElement("MarketValue")
                TextProperty = _
    		DOMProperties.CreateTextNode(FormatNumber(MarketValue))
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Create a node named Description
                PropertyElement = DOMProperties.CreateElement("Description")
                TextProperty = DOMProperties.CreateTextNode(Description)
                RootElement.LastChild.AppendChild(PropertyElement)
                RootElement.LastChild.LastChild.AppendChild(TextProperty)
    
                ' Save the XML file
                DOMProperties.Save(Filename)
    
                If strPicturePath.Length <> 0 Then
                    ' The following code gets a reference to the picture's name 
                    Dim flePicture As FileInfo = New FileInfo(strPicturePath)
                    ' Then it copies it to the directory of this business
                    ' It changes its name to be the same as the property code
                    flePicture.CopyTo("C:\Altair Realtors\" & _
                                      PropertyCode & _
                                      flePicture.Extension)
                End If
    
                ShowListing()
    
                If lvwProperties.Items.Count > 0 Then
                    lvwProperties.Items(0).Selected = True
                End If
            End If
        End Sub
    
        Private Sub ShowListing()
    
        End Sub
    End Class
  33. Execute the application and create a few properties
  34. Close the form and return to your programming environment

Practical Learning: Accessing XML Attributes

  1. Implement the ShowListing procedure as follows:
    Private Sub ShowListing()
            Dim DOMProperties As XmlDocument = New XmlDocument
            Dim Filename As String = "C:\Altair Realtors\properties.xml"
    
            If File.Exists(Filename) Then
                lvwProperties.Items.Clear()
    
                DOMProperties.Load(Filename)
                Dim PropertyElement As XmlElement = DOMProperties.DocumentElement
                Dim ListOfProperties As XmlNodeList = PropertyElement.ChildNodes
    
                Dim i As Integer = 1
    
                For Each Node As XmlNode In ListOfProperties
                    Dim lviProperty As ListViewItem = New ListViewItem(i)
    
                    lviProperty.SubItems.Add(Node.Attributes(0).InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.Attributes(1).InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.NextSibling.InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.NextSibling.NextSibling.InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.NextSibling.NextSibling.NextSibling.InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.NextSibling.NextSibling.NextSibling.NextSibling.InnerText)
                    lviProperty.SubItems.Add(Node.FirstChild.NextSibling.NextSibling.NextSibling.NextSibling.NextSibling.NextSibling.InnerText)
                    lvwProperties.Items.Add(lviProperty)
                    i = i + 1
                Next
    
                txtDescription.Text = ListOfProperties(0)("Description").InnerText
            End If
    End Sub 
  2. In the Class Name combo box, select (RealEstate Events)
  3. In the Method Name combo box, select Load and implement the event as follows:
     
    Private Sub RealEstate_Load(ByVal sender As Object, _
                                    ByVal e As System.EventArgs) _
                                    Handles Me.Load
            ShowListing()
    
            If lvwProperties.Items.Count > 0 Then
                lvwProperties.Items(0).Selected = True
            End If
    End Sub
  4. In the Class name combo box, select lvwProperties
  5. In the Method Name combo box, select SelectedIndexChanged and implement the event as follows:
     
    Private Sub lvwProperties_SelectedIndexChanged(ByVal sender As Object, _
                                                   ByVal e As System.EventArgs) _
                                          Handles lvwProperties.SelectedIndexChanged
        If (lvwProperties.SelectedItems.Count = 0) Or _
           (lvwProperties.SelectedItems.Count > 1) Then
            Exit Sub
        End If
    
        Dim PropertyCode As String = lvwProperties.SelectedItems(0).SubItems(1).Text
    
        ' Make a list of the picture files
        Dim strDirectory As String = "C:\Altair Realtors"
        Dim dirProperties As DirectoryInfo = New DirectoryInfo(strDirectory)
        Dim PictureFiles() As FileInfo = dirProperties.GetFiles()
    
        ' Look for a file that holds the same name as the item number
        For Each fle As FileInfo In PictureFiles
            ' Get the name of the file without its extension
            Dim fwe As String = Path.GetFileNameWithoutExtension(fle.FullName)
             If fwe = PropertyCode Then
                pbxProperty.Image = Image.FromFile(strDirectory & _
                      "\" & PropertyCode + fle.Extension)
            End If
        Next
    
        Dim DOMProperties As XmlDocument = New XmlDocument
        Dim Filename As String = "C:\Altair Realtors\properties.xml"
    
        If File.Exists(Filename) Then
            DOMProperties.Load(Filename)
            Dim PropertyElement As XmlElement = DOMProperties.DocumentElement
            Dim ListOfProperties As XmlNodeList = PropertyElement.ChildNodes
    
            For Each Node As XmlNode In ListOfProperties
                If Node.Attributes(0).InnerText = PropertyCode Then
                    txtDescription.Text = Node("Description").InnerText
                End If
            Next
        End If
    End Sub
  6. In the Class Name combo box, select btnClose
  7. In the Method Name combo box, select Click and implement the event as follows:
     
    Private Sub btnClose_Click(ByVal sender As Object, _
                                   ByVal e As System.EventArgs) _
                                   Handles btnClose.Click
            End
    End Sub
  8. Execute the application

Exercises

 

Altair Realtors

  1. Create a Windows Application named AltairRealtors1a following the same steps as this lesson
  2. Create big pictures of the properties (houses) and save them
  3. Configure the first form so that, if the user double-clicks the picture, another window opens and displays a bigger picture of the house or of the building
  4. Configure the first form so that, if the user double-clicks an item, the property editor opens and displays the corresponding property. Then, if the user modifies a value in the dialog box and clicks OK, you update the same property with the changed value(s)
  5. Make the necessary changes to the application to produce an XML document with the following additional elements and attributes
     
    <Listing>
        <Property Code"000-000" Status="">
            <DateListed YearBuilt=""></DateListed>
            <PropertyType Style="" Condition=""></PropertyType>
            <Location Address="" City="" State="" ZIPCode=""></Location>
            <Stories></Stories>
            <Bedrooms UpperFloor="4" LowerFloor="0" Basement="1">5</Bedrooms>
            <Bathrooms UpperFloor="2" LowerFloor="0.5" Basement="1">3.5</Bathrooms>
            <IndoorGarage Spaces="2">true</IndoorGarage>
            <FinishedBasement Entrance="Common/Rear" FinishedType="Recreation Room/Apartment">true</FinishedBasement>
            <Description></Description>
        </Property>
    </Listing>
 

Home Copyright © 2008-2012 FunctionX