Home

Details on Using Variables

 

Constants

 

Introduction

A constant is a value that doesn't change. There are two types of constants you will use in your programs: those supplied to you and those you define yourself.

To create a constant to use in your program type the Const keyword followed by a name for the variable, followed by the assignment operator "=", and followed by the value that the constant will hold. Here is an example:

Module Module1
    Sub Main()
        Const DateOfBirth = #12/5/1974#

        MsgBox(DateOfBirth)
    End Sub
End Module

When defining a constant like this, the compiler would know the type of data to apply to the variable. In this case the DateOfBirth constant holds a Date value. Still, to be more explicit, you can indicate the type of value of the constant by following its name with the As keyword and the desired data type. Based on this, the above program would be:

Module Module1
    Sub Main()
        Const DateOfBirth As Date = #12/5/1974#

        MsgBox("Date of Birth: " & DateOfBirth)
    End Sub
End Module

When creating a constant, if its value supports a type character, instead of using the As keyword, you can use that type character. Here is an example:

Module Exercise	

    Sub Main()
        Const Temperature% = 52
    End Sub

End Module

As mentioned earlier, the second category of constants are those that are built in the Visual Basic language. Because there are many of them and used in different circumstances, when we need one, we will introduce and then use it.

Practical LearningPractical Learning: Using Constants

  1. Start Microsoft Visual Basic
  2. To create a new application, on the Start Page, on the right side of Create, click Project
  3. In the Templates section, click Console Application
  4. In the Name text box, replace the name with GeorgetownDryCleaner
  5. In the Solution Name, replace the name with Variables3
  6. Click OK
  7. In the Solution Explorer, under GeorgetownDryCleaner1, right-click Module1.vb and click Rename
  8. Type GeorgetownDryCleaner.vb and press Enter
  9. To deal with new dates and times, change the program as follows:
     
    Module GeorgetownDryCleaner
    
        Sub Main()
            Const UnitPriceShirts As Double = 1.25
            Const UnitPricePants As Double = 1.95
            Const UnitPriceOtherItems As Double = 3.25
            Const TaxRate As Double = 5.75
    
            Dim CustomerName As String, CustomerPhone As String
            Dim OrderDate As Date, OrderTime As Date
            ' Unsigned numbers to represent cleaning items
            Dim NumberOfShirts As UInteger, NumberOfPants As UInteger
            Dim NumberOfOtherItems As UInteger
            ' Each of these sub totals will be used for cleaning items
            Dim SubTotalShirts As Double, SubTotalPants As Double
            Dim SubTotalOtherItems As Double
            ' Values used to process an order
            Dim TotalOrder As Double, TaxAmount As Double
            Dim NetTotal As Double
            Dim AmountTended As Double
    
            ' Request order information from the user
            CustomerName = InputBox("Enter Customer Name:")
            CustomerPhone = InputBox("Enter Customer Phone:")
            OrderDate = InputBox("Enter the order date:")
            OrderTime = InputBox("Enter the order time:")
    
            NumberOfShirts = InputBox("Enter Number of Shirts")
            NumberOfPants = InputBox("Enter Number of Pants")
            NumberOfOtherItems = InputBox("Enter Number of Other Items")
    
            ' Perform the necessary calculations
            SubTotalShirts = NumberOfShirts * UnitPriceShirts
            SubTotalPants = NumberOfPants * UnitPricePants
            SubTotalOtherItems = NumberOfOtherItems * UnitPriceOtherItems
            ' Calculate the "temporary" total of the order
            TotalOrder = SubTotalShirts + SubTotalPants + SubTotalOtherItems
    
            ' Calculate the tax amount using a constant rate
            TaxAmount = TotalOrder * TaxRate / 100
            ' Add the tax amount to the total order
            NetTotal = TotalOrder + TaxAmount
    
            ' Communicate the total to the user...
            MsgBox("The Total order is: " & NetTotal)
            ' and request money for the order
            AmountTended = InputBox("Amount Tended?")
    
            MsgBox(vbTab & "-/- Georgetown Dry Cleaner -/-" & vbCrLf & _
                   "==============================" & vbCrLf & _
                   vbTab & "Customer Name: " & CustomerName & vbCrLf & _
                   vbTab & "Customer Phone: " & CustomerPhone & vbCrLf & _
                   vbTab & "Order Date: " & OrderDate & vbCrLf & _
                   vbTab & "Order Time: " & OrderTime & vbCrLf & _
               "------------------------------------------------------------" _
                   & vbCrLf & _
                   "Item Type" & vbTab & "Qty" & vbTab & "Unit/Price" _
                   & vbTab & "Sub-Total" & vbCrLf & _
               "------------------------------------------------------------" _
                   & vbCrLf & _
                   "Shirts " & vbTab & vbTab & CStr(NumberOfShirts) & vbTab _
                   & CStr(UnitPriceShirts) & vbTab & _
    		CStr(SubTotalShirts) & vbCrLf & _
                   "Pants " & vbTab & vbTab & CStr(NumberOfPants) & vbTab & _
                   CStr(UnitPricePants) & vbTab & CStr(SubTotalPants) & _
    	       vbCrLf & "Other Items " & vbTab & CStr(NumberOfOtherItems) & _
    	       vbTab & CStr(UnitPriceOtherItems) & vbTab _
    		& CStr(SubTotalOtherItems) & vbCrLf & _
                "-----------------------------------------------------------" _
                   & vbCrLf & _
                   vbTab & "Total Cleaning: " & vbTab & _
    		CStr(TotalOrder) & vbCrLf & _
                   vbTab & "Tax Rate: " & vbTab & CStr(TaxRate) & "%" & vbCrLf & _
                   vbTab & "Tax Amount: " & vbTab & CStr(TaxAmount) & vbCrLf & _
                   vbTab & "Net Price: " & vbTab & CStr(NetTotal) & vbCrLf & _
                   "==============================")
        End Sub
    
    End Module
  10. Execute the program
  11. Enter values as follows:
     
    Customer Name: Jeannette Sharma
    Customer Phone: (301) 218-9000
    Order Date: 04/11/2008
    Order Time 08:24
    Number of Shirts: 6
    Number of Pants: 4
    Number of Other Items: 2
     
  12. Enter the amount tended as 40
     
    Georgetown Dry Cleaner
  13. Close the message box and the DOS window to return to your programming environment

Nothing

So far, to initialize a variable, we were using a known value. Alternatively, you can use the Nothing constant to initialize a variable, simply indicating that it holds a value that is not (yet) defined. Here is an example:

Module Module1

    Sub Main()
        Dim DateOfBirth As Date = Nothing
    End Sub

End Module

If you use the Nothing keyword to initialize a variable, the variable is actually initialized to the default value of its type. For example, a number would be assigned 0, a date would be assigned January 1, 0001 at midnight.

The Scope and Lifetime of a Variable 

 

Local Variables

The scope of a variable determines the areas of code where the variable is available. You may have noticed that, so far, we declared all our variables only inside of Main(). Actually, the Visual Basic language allows you to declare variables outside of Main() (and outside of a particular procedure).

A variable declared inside of a procedure such as Main() is referred to as a local variable. Such as variable cannot be accessed by another part (such as another procedure) of the program.

Global Variables

A variable that is declared outside of any procedure is referred to as global. To declare a global variable, use the same formula as we have done so far. For example, just above the Sub Main() line, you can type Dim, followed by the name of the variable, the As keyword, its type and an optional initialization. Here is an example:

Module Module1

    Dim DateOfBirth As Date

    Sub Main()
        
    End Sub

End Module

As mentioned above, you can initialize the global variable when or after declaring it. Here are two examples:

Module Module1

    Dim UnitPrice As Double
    Dim DateOfBirth As Date = #12/5/1974#

    Sub Main()
        UnitPrice = 24.95
        MsgBox("Date of Birth: " & DateOfBirth)
        MsgBox("Unit Price: " & UnitPrice)
    End Sub

End Module

As we will see when studying procedures, a global variable can be accessed by any other procedure (or even class) of the same file. In most cases, a global variable must be declared inside of a module, that is, between the Module ModName and the End Module lines but outside of a procedure. Based on this, such a variable is said to have module scope because it is available to anything inside of that module.

Practical LearningPractical Learning: Declaring Global Constants

  1. Change the document as follows:
     
    Module GeorgetownDryCleaner
    
        Const UnitPriceShirts As Double = 1.25
        Const UnitPricePants As Double = 1.95
        Const UnitPriceOtherItems As Double = 3.25
        Const TaxRate As Double = 5.75
    
        Sub Main()
    
            Dim CustomerName As String, CustomerPhone As String
            
    	. . . No Change
    
        End Sub
    
    End Module
  2. Execute the program
  3. Enter values as follows:
     
    Customer Name: Shawn Nitty
    Customer Phone: (301) 423-7744
    Order Date: 04/11/2008
    Order Time 09:12
    Number of Shirts: 0
    Number of Pants: 2
    Number of Other Items: 0
  4. Enter the amount tended as 20
  5. Close the message box and the DOS window to return to your programming environment

Modules

 

Introduction

In the small programs we have created so far, we were using only one file. A typical application uses as many files as necessary. You can use one file to list some objects used in other files. As we move on, we will see different examples of creating different files in the same program.

In the Visual Basic language, a file that holds Visual Basic code is called a module.

Creating a Module

As mentioned above, a module is primarily a file that holds code. Therefore, there is no complication with creating one. It is simply a file that holds the .vb extension. If you create a console application using the Console Application option of the New Project dialog box, Microsoft Visual Studio would create a default file for and would insert the module template code.

To create a module in Microsoft Visual Studio or Microsoft Visual Basic 2008 Express Edition, on the main menu, you can click Project -> Add Module... This would display the Add New Item dialog box with the Module selected as default in the Templates list. The studio would also suggest a default name. You can accept that name or change it. The name of the module follows the rules of an object in the Visual Basic language. Once you are ready with the dialog box, you can click Add.

If you are manually creating your code from Notepad or any text editor, you can simply create any file in your folder and give it the .vb extension.

Probably the most important thing in a module is that the area that contains its code must start with a Module ModuleName and end with an End Module line:

Module ModuleName

End Module

Anything between these two lines is part of the normal code and everything that is normal code of the module must be inserted between these two lines. No code should be written outside of these two lines.

After creating a module and adding its required two lines, you can add the necessary code. Of course, there are rules you must follow.

At a minimum, you can declare one or more variables in a module, just as we have done so far. Here is an example:

Module Module1
    Dim FullName As String
End Module
 

Access Modifiers

 

Introduction

As mentioned already, you can use more than one module in a project and you can declare variables in a module. This allows different modules to exchange information. For example, if you are planning to use the same variable in more than section of your application, you can declare the variable in one module and access that variable in any other module in the application.

The Friendly Members of a Module

A variable that is declared in one module and can be accessed from another module in the same application is referred to as a friend. Variables are not the only things that can benefit from this characteristic. We will see other types.

To declare a friendly variable, instead of Dim, you use the Friend keyword. Here is an example:

Module Module1
    Friend FullName As String
End Module

After declaring such a variable, you can access it from any module of the same application. Here is an example:

File 1: Module1.vb
Module Module1
    Friend FullName As String
End Module
 
File 2: Exercise.vb
Module Exercise
    Sub Main()
        FullName = "Gertrude Monay"
        MsgBox("Full Name: " & FullName)
    End Sub
End Module

The Private Members of a Module

Instead of allowing a member of a module to be accessible outside the module, you may want to restrict  this access. The Visual Basic language allows you to declare a variable that can be accessed only within the module that contains it. No code outside the module would be able to "see" such a member. A member inside a module and that is hidden from other modules is referred to as private.

To declare a private variable, instead of Dim or Friend, you use the Private keyword. Here is an example:

Module Exercise
    Friend FullName As String
    Private DateHired As Date

    Sub Main()
        FullName = "Gertrude Monay"
        DateHired = #4/8/2008#
        Dim Information As String

        Information = "Full Name: " & FullName & _
                      vbCrLf & _
                      "Date Hired: " & DateHired
        MsgBox(Information)
    End Sub

End Module

This would produce:

Private

Practical LearningPractical Learning: Declaring Global Private Variables

  1. Change the document as follows:
     
    Module GeorgetownDryCleaner
    
        Const UnitPriceShirts As Double = 1.25
        Const UnitPricePants As Double = 1.95
        Const UnitPriceOtherItems As Double = 3.25
        Const TaxRate As Double = 5.75
    
        Private CustomerName As String, CustomerPhone As String
        Private OrderDate As Date, OrderTime As Date
        ' Unsigned numbers to represent cleaning items
        Private NumberOfShirts As UInteger, NumberOfPants As UInteger
        Private NumberOfOtherItems As UInteger
        ' Each of these sub totals will be used for cleaning items
        Private SubTotalShirts As Double, SubTotalPants As Double
        Private SubTotalOtherItems As Double
        ' Values used to process an order
        Private TotalOrder As Double, TaxAmount As Double
        Private NetTotal As Double
        Private AmountTended As Double
    
        Sub Main()
            ' Request order information from the user
            CustomerName = InputBox("Enter Customer Name:")
            
    	. . . No Change
            
        End Sub
    
    End Module
  2. Execute the program
  3. Enter values as follows:
     
    Customer Name: Landry Kurtzmann
    Customer Phone: (202) 223-3325
    Order Date: 04/12/2008
    Order Time 07:35
    Number of Shirts: 8
    Number of Pants: 2
    Number of Other Items: 0
  4. Enter the amount tended as 50
  5. Close the message box and the DOS window to return to your programming environment

The Public Members of a Module

When working on a project, you may want to create objects or declare variables that you want to be accessible from other applications. Such a member is referred to as public.

To declare a variable that can be accessed by the same modules of the same project and modules of other projects, declare it using the Public keyword. Here is an example:

Module Exercise
    Private DateHired As Date
    Public HourlySalary As Double

    Sub Main()
        FullName = "Gertrude Monay"
        DateHired = #4/8/2008#
        HourlySalary = 36.75
        Dim Information As String

        Information = "Full Name: " & FullName & _
                      vbCrLf & _
                      "Date Hired: " & DateHired & _
                      vbCrLf & _
                      "Hourly Salary: " & HourlySalary
        MsgBox(Information)
    End Sub
End Module

This would produce:

Public

Access Modifiers and Modules

The Friend, Private, and Public keywords are called access modifiers because they control the level of access that a member of a module has. In previous sections, we saw how to control the members of a module. The level of access of a module itself can also be controlled. To control the level of access of a module, you can precede the Module keyword with the desired access modifier.

The access modifier of a module can only be either Friend or Public. Here are examples:

File 1: Module1.vb
Friend Module Module1
    
End Module
 
File 2: Module2.vb
Public Module Module1
    
End Module
  • If a module is set to Friend, its Public and Friend members can be accessed by other members of modules of the same application. The public members cannot be accessed outside of the same application. This means that if you create an application A that has a friend module M and that module contains a public variable V, that variable V cannot be accessed by a module N from another application B
  • If a module is set Public:
    • Its Friend members can be accessed by friend and public modules of the same application. The friend members cannot be accessed outside of its application (even if the module is Public)
    • Its Public members can be accessed by modules inside the same application and modules in other applications (outside its application)

Practical LearningPractical Learning: Access Modifying a Module

  1. Change the document as follows:
     
    Public Module GeorgetownDryCleaner
    
        . . . No Change
    
    End Module
  2. Execute the program
  3. Enter values as follows:
     
    Customer Name: William Nessif
    Customer Phone: (301) 220-3737
    Order Date: 04/12/2008
    Order Time 08:26
    Number of Shirts: 3
    Number of Pants: 3
    Number of Other Items: 3
  4. Enter the amount tended as 40
  5. Close the message box and the DOS window to return to your programming environment

Details on Declaring Variables

 

Declaring a Series of Variables

Because a program can use different variables, you can declare each variable on its own line. Here are examples:

Module Exercise
    Sub Main()
        Dim NumberOfPages As Integer
        Dim TownName As String
        Dim MagazinePrice As Double
    End Sub
End Module

It is important to know that different variables can be declared with the same data type as in the following example:

Module Exercise
    Sub Main()
        Dim NumberOfPages As Integer
        Dim Category As Integer
        Dim MagazinePrice As Double
    End Sub
End Module

When two variables use the same data type, instead of declaring each on its own line, you can declare two or more of these variables on the same line. There are two techniques you can use:

  • You can write the names of both variables on the same line, separated by a comma, and ending the line with the common data type:
     
    Module Exercise
        Sub Main()
            Dim NumberOfPages, Category As Integer
            Dim MagazinePrice As Double
        End Sub
    End Module

    In this case, both variables NumberOfPages and Category, are the same type, Integer

  • You can also declare, on the same line, variables that use different data types. To do this, type the Dim keyword followed by the variable name and its data type with the As keyword. Then type a comma, followed by the other variable(s) and data type(s). Here is an example
     
    Module Exercise
        Sub Main()
            Dim NumberOfPages, Category As Integer
            Dim CountryName As String, MagazinePrice As Double
        End Sub
    End Module

    In this case, CountryName is a string variable while MagazinePrice is a Double variable

You can use the same techniques when declaring many global variables. Here are examples:

Module Exercise
    Friend FirstName As String, LastName As String
    Private DateHired As Date, HourlySalary As Double

    Sub Main()
        
    End Sub

End Module

After declaring the variables, you can initialize and use them as you see fit.

Read-Only Variables

We have indicated that when a variable is declared, it receives a default initialization unless you decide to specify its value. Whether such a variable has been initialized or not, at any time, you can change its value by reassigning it a new one. Here is an example:

Module Exercise

    Sub Main()
        ' Initializing a variable when declaring it
        Dim Number As Double = 155.82
        MsgBox("Number: " & Number)

        ' Changing the value of a variable after using it
        Number = 46008.39
        MsgBox("Number: " & Number)
    End Sub

End Module

This would produce:

Number

Number

In the same way, we saw that you could declare a variable at module scope outside of Main and then initialize or change its value when necessary. Here is an example:

Module Exercise

    Private UnitPrice As Double
    Private DateOfBirth As Date = #12/5/1974#
    Private Number As Double

    Sub Main()
        ' Initializing a variable
        Number = 155.82
        MsgBox("Number: " & Number)

        ' Changing the value of a variable after using it
        Number = 46008.39
        MsgBox("Number: " & Number)
    End Sub

End Module

When declaring a variable, as the programmer, you should have an idea of how you want to use the variable and what type of values the variable should hold. In some cases, you may want the variable to hold a constant value and not be able to change it. We saw earlier that such a variable could be declared as a constant. An alternative is to declare it with the ReadOnly keyword. While a constant variable can be declared locally, a ReadOnly variable cannot. It must be declared globally.

As done for a constant, when declaring a ReadOnly variable, you should initialize it. If you do not, the compiler would assign the default value based on its type. For example, a number-based variable would be initialized with 0 and a String variable would be initialized with an empty string. As done so far, to initialize the variable, use the assignment operator followed by the desired value.

Like a constant, after declaring and optionally initializing a ReadOnly variable, you cannot change its value. Based on this, the following code would produce an error:

Module Module1

    Dim UnitPrice As Double
    Dim DateOfBirth As Date = #12/5/1974#
    ReadOnly Number As Double = 155.82

    Sub Main()
        ' Initializing a variable
        Number = 155.82
        MsgBox("Number: " & Number)

        ' Changing the value of a variable after using it
        Number = 46008.39 ' Error: You cannot assign a value to
        '                   a ReadOnly variable after initializing it
        MsgBox("Number: " & Number)
    End Sub

End Module

In the Microsoft Visual Basic 2008, the parser would signal the errors by underlining the read-only variable when you try changing its value:

In the Microsoft Visual Basic 2008, the parser would signal the errors

This means that a ReadOnly variable must be assigned a value once, when initializing it.

 

 
 

Previous Copyright © 2008-2010 FunctionX Next